远子 💖 Vina

借助 AppleScript 一键打开工作空间

远子 •  2021年01月18日 • 评论

image.png

我有个小毛病:同时只能在一个工程里工作。

假如让我开四五个 Webstorm,在工程里 A 改个Bug,然后又到工程 B 里加个需求,再去工程 C 发个版,切来切去一会儿就懵了。

于是有了这个项目:my-applescript

使用方式

  1. 第一步:鼠标滑动到左侧底部唤起桌面(我设置的触发角);
  2. 第二步:双击 “open-saas-admin”(是个脚本,会初始化公司 saas-admin 项目的工作空间);
  3. 第三步:泡个茶或者发个呆,脚本负责打开 Webstorm、iTerm、Chrome、执行开发命令...
  4. 第四步:干活儿。

如何实现

思路很简单:用 AppleScript 控制 MacOS 中的应用程序

下边是一段示例代码:

set dirPath to "/Users/rmlzy/Documents/homedo/saas-admin"

on quitApplication(name)
    tell application name
        quit
    end tell
end quitApplication

on runCmdInNewTab(cmdStrs)
    tell application "iTerm"
        activate
        delay 1
        tell current window
            create tab with default profile
            tell current session
                repeat with cmdStr in cmdStrs
                    write text cmdStr
                end repeat
            end tell
        end tell
    end tell
end runCmdInNewTab

on openChrome(URL)
    tell application "Google Chrome"
        activate
        open location URL
    end tell
end openChrome

# Fire
quitApplication("iTerm")
delay 1
quitApplication("Webstorm")
delay 1
runCmdInNewTab({"pwd", "cd " & dirPath, "git pull", "npm run dev"})
runCmdInNewTab({"webstorm " & dirPath})
openChrome("http://localhost:10445")

AppleScript 的语法很简单,套娃式的逻辑结构。

脚本实现以后,可以在 MacOS 中的 “Script Editor” 中测试一下。

测试完毕后,点击目录中的 “文件”,选择 “导出”,导出成应用程序到桌面,勾选“仅运行” 即可。

完工。


我要发表看法

«-必填
«-必填,不公开